Windows의 가로 스크롤 바로 가기

다음은 shift 및 (아마도) 기본 마우스 휠 스크롤 명령을 사용하여 수행하는 AutoHotKey 스크립트입니다.

; Shift + Wheel for horizontal scrolling
+WheelDown::WheelRight
+WheelUp::WheelLeft

이것은 https://Gist.github.com/cheeaun/160999 에서 직접 가져옵니다.

Microsoft 응용 프로그램을 포함한 많은 응용 프로그램은 수평 마우스 휠 스크롤을 지원하지 않습니다. (이 기능은 Windows Vista에서만 도입되었다고 생각합니다.)

http://www.autohotkey.com/docs/Hotkeys.htm 에서

마우스 휠에 가장 유용한 단축키는 창의 텍스트를 스크롤하는 다른 모드를 포함합니다. 예를 들어, 왼쪽 단축 키를 누른 상태에서 휠을 돌리면 다음 단축키 쌍이 수직이 아닌 수평으로 스크롤됩니다.

~LControl & WheelUp::  ; Scroll left.
ControlGetFocus, fcontrol, A
Loop 2  ; <-- Increase this value to scroll faster.
    SendMessage, 0x114, 0, 0, %fcontrol%, A  ; 0x114 is WM_HSCROLL and the 0 after it is SB_LINELEFT.
return

~LControl & WheelDown::  ; Scroll right.
ControlGetFocus, fcontrol, A
Loop 2  ; <-- Increase this value to scroll faster.
    SendMessage, 0x114, 1, 0, %fcontrol%, A  ; 0x114 is WM_HSCROLL and the 1 after it is SB_LINERIGHT.
return

마우스 오른쪽 버튼으로 Windows에서이를 수행하는 방법이 있습니다. 조그 왼쪽/조그 오른쪽 버튼이 오른쪽에 통합 된 스크롤 휠이있는 마우스가 있습니다. 스크롤 휠을 왼쪽이나 오른쪽으로 누르면 내용이 원하는 방향으로 이동합니다. Logitech VX를 보유하고 있으며 매우 만족합니다.

또한 VX를 사용하면 기울어 진 경우 단일 응용 프로그램마다 단추를 다르게 구성 할 수 있습니다. 이 수준의 커스터마이징은 매우 기쁩니다!

일부 Windows 프로그램에서는 Shift가 가로로 스크롤됩니다 (예 : Windows 탐색기).

Internet Explorer, Firefox 및 Excel과 같은 다른 프로그램에서는 스크롤 휠 버튼을 누른 채 왼쪽에서 오른쪽으로 이동하면 가로로 스크롤됩니다.

키보드 단축키는 아니지만 항상 마우스 휠을 클릭 할 수 있습니다. 스크롤하는 데 사용할 수있는 대부분의 응용 프로그램에 4 방향 아이콘이 나타납니다.

다음은 AutoHotKey 및 Word 매크로가 모두 필요한 Word 전용 솔루션입니다. Word의 주 문서보기에서만 작동합니다 (나에게 충분합니다).

먼저 AutoHotKey를 사용하여 마우스 동작에 대한 응답으로 사용자 지정 키 입력을 Word로 보냅니다. Alt-M RightArrow 및 Alt-M LeftArrow를 사용하고 있습니다. (또한 마우스가 제대로 전송하기 때문에 WheelLeft 및 WheelRight 이벤트에 대한 매핑이 있습니다. 유용한 기능을 수행하려면 Word가 필요합니다.)

#If WinActive("ahk_class OpusApp")
+WheelUp::SendInput !+M{Left}
WheelLeft::SendInput !+M{Left}
WheelRight::SendInput !+M{Right}
+WheelDown::SendInput !+M{Right}
#If

Word 키 바인딩을 설정하십시오 (키보드 사용자 정의 대화 상자를 사용하여이를 수행 할 수도 있음).

' Alt-Shift-M Right (keycode 39)
KeyBindings.Add KeyCode:=BuildKeyCode(wdKeyM, wdKeyShift, wdKeyAlt), _
    KeyCode2:=BuildKeyCode(39), _
    KeyCategory:=wdKeyCategoryMacro, Command:="Normal.NewMacros.ScrollRight"

' Alt-Shift-M Left (keycode 37)
KeyBindings.Add KeyCode:=BuildKeyCode(wdKeyM, wdKeyShift, wdKeyAlt), _
    KeyCode2:=BuildKeyCode(37), _
    KeyCategory:=wdKeyCategoryMacro, Command:="Normal.NewMacros.ScrollLeft"

마지막으로 일반 템플릿에서 Word 매크로를 정의하거나 위의 참조를 조정하십시오.

Sub ScrollRight()
    ActiveWindow.SmallScroll ToRight:=1
End Sub
Sub ScrollLeft()
    ActiveWindow.SmallScroll ToLeft:=1
End Sub

Sam 솔루션에서 구성 가능한 스크롤 속도를 가진 자체 솔루션을 개발했습니다.

https://Gist.github.com/envil/d21a24744b68fda626b4444784f71c32

; Shift + Wheel for horizontal scrolling
+WheelUp::
    ; Scroll to the left
    MouseGetPos,,,id, fcontrol,1
    Loop 8 ; <-- Increase for faster scrolling
        SendMessage, 0x114, 0, 0, %fcontrol%, ahk_id %id% ; 0x114 is WM_HSCROLL and the 0 after it is SB_LINERIGHT.
return
+WheelDown::
    ;Scroll to the right
    MouseGetPos,,,id, fcontrol,1
    Loop 8 ; <-- Increase for faster scrolling
        SendMessage, 0x114, 1, 0, %fcontrol%, ahk_id %id% ;  0x114 is WM_HSCROLL and the 1 after it is SB_LINELEFT.
return

주변을 둘러 본 후에는 결과를 얻지 못하더라도 Excel과 다른 곳에서 작동하는 방법 ( AutoHotKey 사용)을 찾았습니다 (AutoHotKey 포럼의 두 가지 다른 솔루션에서 적용됨). 소스를 기록하여 적절한 크레딧을 줄 수 없습니다.).

MS Excel은 사용자 인터페이스를 처리하는 strange 방법을 가지고있는 것 같습니다 (어쨌든 MS Office 개발자가 우리에게 무엇을 주 었는지 몇 년이 지난 후에도 놀라지 않았습니다). 이 스크립트는 MS Word를 제외하고 거의 모든 곳에서 작동하는 것 같습니다. 누군가가 해결할 수 있다면 알려주십시오! 아마도 Word의 창 클래스를 찾고 Excel을 사용하여 수행 한 것과 같은 코드를 코딩하는 것과 같은 것일 수 있습니다 (다른 키 바인딩 세트 만 사용).

#Singleinstance Force
#IfWinActive ahk_class XLMAIN
+WheelUp::
SetScrollLockState, On
SendInput {Left}
SetScrollLockState, Off
Return
+WheelDown::
SetScrollLockState, On
SendInput {Right}
SetScrollLockState, Off
Return

; Everything except Excel.
#IfWinNotActive ahk_class XLMAIN
+WheelUp::  ; Scroll left.
ControlGetFocus, fcontrol, A
Loop 4  ; <-- Increase this value to scroll faster.
    SendMessage, 0x114, 0, 0, %fcontrol%, A  ; 0x114 is WM_HSCROLL and the 0 after it is SB_LINELEFT.
return

+WheelDown::  ; Scroll right.
ControlGetFocus, fcontrol, A
Loop 4  ; <-- Increase this value to scroll faster.
    SendMessage, 0x114, 1, 0, %fcontrol%, A  ; 0x114 is WM_HSCROLL and the 1 after it is SB_LINERIGHT.
return
#IfWinActive

다른 수정 자의 다양한 기능 (예 : ctrl + scroll zoom)을 유지하면서 모든 응용 프로그램에서 horiz 스크롤이 작동하도록 혼합 된 여러 스크립트를 시도했습니다.

위의 u/np8 AHK 스크립트는 선택한 최상의 답변이 아닌 곳에서 완벽하게 작동합니다.

로지텍 인터페이스

Logitech 게임 인터페이스에서 다양한 스크립트와 매크로가 활성화 된 Logitech G500을 사용하고 있으며이 스크립트에는 호환성/충돌 문제가 없습니다.

Logitech Interface에서 나는 스크롤 업/아래로 스크롤하여 휠에서 왼쪽으로 스크롤/오른쪽으로 스크롤하고 스크립트를 시작하고 프로그램을 다시 시작했으며 시도한 모든 앱에서 성공했습니다.

• 워드
• 뛰어나다
• 브라우저
• Adobe 앱 (다양한, 일부는 특별한 앱 기능이 있습니다>)

허용 된 답변을 편집하는 것이 두 번 거부되었으므로 별도의 답변에 내 오토 핫키 scipts 추가

오토 핫키 설정

AutoHotKey를 처음 사용하는 사람들을 위해 다음 단계가 있습니다.

1) Download and install AutoHotKey from autohotkey.com 
2) Right click on your desktop (or any other folder) -> New 
   -> Text Document -> Make a file called "myscript.ahk" 
3) Copy-paste the script from below -> Save the file 
4) Right-click on the file -> Run Script 
5) Small H-icon should appear to your taskbar notification area

힌트 : Windows 시작시 스크립트를 자동으로 실행 를 원할 수 있습니다.

오토 핫키 스크립트

; Default solution (for all other programs)
; Shift + Wheel for horizontal scrolling
+WheelDown::WheelRight
+WheelUp::WheelLeft

; MS Excel
#IfWinActive, ahk_exe Excel.EXE

; Shift + Wheel for horizontal scrolling (left)
~LShift & WheelUp::
    {
        SetScrollLockState, on
        send,{left}
        SetScrollLockState, off
    }
return

; Shift + Wheel for horizontal scrolling (right)
~LShift & WheelDown:: 
    {
        SetScrollLockState, on
        send,{right}
        SetScrollLockState, off
    }
return

#IfWinActive